mock_provider "aws" {
  mock_data "aws_ec2_instance_type_offerings" { defaults = { locations = ["eu-west-1a", "eu-west-1b"] } }
  mock_data "aws_region" { defaults = { region = "eu-west-1" } }
  mock_data "aws_availability_zones" { defaults = { names = ["eu-west-1a", "eu-west-1b"] } }
  mock_data "aws_ami" { defaults = { id = "ami-0123456789abcdef0" } }
  mock_resource "aws_s3_bucket" { defaults = { arn = "arn:aws:s3:::mock-test-bucket", id = "mock-test-bucket" } }
  mock_resource "aws_iam_role" { defaults = { arn = "arn:aws:iam::123456789012:role/test" } }
}

variables {
  name                   = "test-carlos-eu-west-1"
  host_count             = 2
  vpc_cidr               = "10.40.0.0/16"
  deployment_bucket_name = "test-platform"
  deployment_bucket_arn  = "arn:aws:s3:::test-platform"
  deployment_region      = "eu-west-2"
  data_bucket_name       = "test-data"
  data_bucket_arn        = "arn:aws:s3:::test-data"
  placement_region       = "primary"
  release_public_key     = "AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA="
  apps_domain            = "apps.example.com"
}
run "host_security" {
  assert {
    condition     = alltrue([for h in aws_instance.host : h.disable_api_termination && !h.root_block_device[0].delete_on_termination]) && length(aws_cloudwatch_metric_alarm.recover) == 2
    error_message = "Protect hosts from accidental termination and retain their disks."
  }
  assert {
    condition     = toset(jsondecode(aws_iam_role_policy.buckets.policy).Statement[1].Resource) == toset(["arn:aws:s3:::test-platform", "arn:aws:s3:::test-data"])
    error_message = "Bucket listing must stay within this deployment and region."
  }
  command = plan
  assert {
    condition     = alltrue([for h in aws_instance.host : h.metadata_options[0].http_tokens == "required" && h.root_block_device[0].encrypted])
    error_message = "Hosts require IMDSv2 and encrypted disks."
  }
  assert {
    condition     = toset([for r in aws_security_group.host.ingress : r.from_port]) == toset([80, 443]) && alltrue([for r in aws_security_group.host.ingress : r.protocol == "tcp" && r.from_port == r.to_port])
    error_message = "Only HTTP and HTTPS ingress is allowed."
  }
  assert {
    condition     = jsondecode(aws_iam_role_policy.deny_parameters.policy).Statement[0].Effect == "Deny" && jsondecode(aws_iam_role_policy.deny_parameters.policy).Statement[0].Resource == "*" && toset(jsondecode(aws_iam_role_policy.deny_parameters.policy).Statement[0].Action) == toset(["ssm:GetParameter", "ssm:GetParameters", "ssm:GetParameterHistory", "ssm:GetParametersByPath"])
    error_message = "SSM must not grant hosts access to operator parameters."
  }
  assert {
    condition     = toset(jsondecode(aws_iam_role_policy.buckets.policy).Statement[0].Resource) == toset(["arn:aws:s3:::test-platform/*", "arn:aws:s3:::test-data/*"])
    error_message = "Bucket writes must stay within control and local data buckets."
  }
  assert {
    condition     = aws_subnet.public[0].availability_zone != aws_subnet.public[1].availability_zone
    error_message = "Hosts must spread across available zones."
  }
  assert {
    condition     = strcontains(aws_instance.host["host-0"].user_data, "AWS_REGION=eu-west-2") && strcontains(aws_instance.host["host-0"].user_data, "CARLOS_HIBERNATE_REGION=eu-west-1")
    error_message = "Control and data bucket regions must remain distinct."
  }
  assert {
    condition     = strcontains(aws_instance.host["host-0"].user_data, "sha256sum -c -") && !strcontains(aws_instance.host["host-0"].user_data, "CARLOS_RELEASE_KEY=")
    error_message = "Bootstrap must check downloads and must not carry a private signing key."
  }
}

run "reject_module_injection" {
  command = plan
  variables { data_bucket_name = "test-data\nENVEOF\necho bad" }
  expect_failures = [var.data_bucket_name]
}