provider "aws" {
  alias               = "primary"
  region              = var.primary_region
  allowed_account_ids = [var.aws_account_id]
  default_tags { tags = { Project = var.name, ManagedBy = "OpenTofu" } }
}
provider "aws" {
  alias               = "secondary"
  region              = var.secondary_region
  allowed_account_ids = [var.aws_account_id]
  default_tags { tags = { Project = var.name, ManagedBy = "OpenTofu" } }
}
module "deployment" {
  control_plane = true
  source        = "../../modules/storage"
  providers     = { aws = aws.primary }
  name          = "${var.name}-${var.aws_account_id}-platform"
}
module "primary_data" {
  source    = "../../modules/storage"
  providers = { aws = aws.primary }
  name      = "${var.name}-${var.aws_account_id}-${var.primary_region}-data"
}
module "secondary_data" {
  source    = "../../modules/storage"
  providers = { aws = aws.secondary }
  name      = "${var.name}-${var.aws_account_id}-${var.secondary_region}-data"
}
module "primary" {
  source                 = "../../modules/region"
  providers              = { aws = aws.primary }
  name                   = "${var.name}-${var.primary_region}"
  host_count             = 1
  vpc_cidr               = "10.40.0.0/16"
  deployment_bucket_name = module.deployment.name
  deployment_bucket_arn  = module.deployment.arn
  deployment_region      = var.primary_region
  data_bucket_name       = module.primary_data.name
  data_bucket_arn        = module.primary_data.arn
  placement_region       = "primary"
  release_public_key     = var.release_public_key
  apps_domain            = var.apps_domain
  instance_type          = var.instance_type
  root_volume_gib        = var.root_volume_gib
}
module "secondary" {
  source                 = "../../modules/region"
  providers              = { aws = aws.secondary }
  name                   = "${var.name}-${var.secondary_region}"
  host_count             = 1
  vpc_cidr               = "10.41.0.0/16"
  deployment_bucket_name = module.deployment.name
  deployment_bucket_arn  = module.deployment.arn
  deployment_region      = var.primary_region
  data_bucket_name       = module.secondary_data.name
  data_bucket_arn        = module.secondary_data.arn
  placement_region       = "secondary"
  release_public_key     = var.release_public_key
  apps_domain            = var.apps_domain
  instance_type          = var.instance_type
  root_volume_gib        = var.root_volume_gib
}
output "hosts" { value = { primary = module.primary.hosts, secondary = module.secondary.hosts } }
output "deployment_bucket" { value = module.deployment.name }
output "data_buckets" { value = { primary = module.primary_data.name, secondary = module.secondary_data.name } }